/*

* $Id: Set_IRC_Channel.bsh 28 2003-03-25 22:40:28Z oliver $

*/



import javax.swing.border.EmptyBorder;



IRCChannelDialog()

{

	dialog = new JDialog(view, "Set IRC Channel", true);

	content = new JPanel(new BorderLayout());

	content.setBorder(new EmptyBorder(12,12,12,12));

	dialog.setContentPane(content);

	channel = new JTextField();

	_channel = jEdit.getProperty("options.irc.channel","#jedit");

	channel.setText(_channel);

	content.add(channel, BorderLayout.CENTER);



	buttonPanel = new JPanel();

	buttonPanel.setLayout(new BoxLayout(buttonPanel, 

		BoxLayout.X_AXIS));



	buttonPanel.setBorder(new EmptyBorder(12,50,0,50));

	buttonPanel.add(Box.createGlue());

	ok = new JButton("OK");

	close = new JButton("Close");

	ok.setPreferredSize(close.getPreferredSize());

	dialog.getRootPane().setDefaultButton(ok);

	buttonPanel.add(ok);

	buttonPanel.add(Box.createHorizontalStrut(6));

	buttonPanel.add(close);

	buttonPanel.add(Box.createGlue());

	content.add(buttonPanel, BorderLayout.SOUTH);



	// {{{ actionPerformed

	void actionPerformed(evt)

	{

		if(evt.getSource() == ok)

		{

			if(!channel.getText().equals(_channel))

			{

				jEdit.setProperty("options.irc.channel", channel.getText());

				jEdit.propertiesChanged();

			}

		}

		dialog.dispose();

		dialog = null;

	}	// }}}



	// {{{ KeyListener implementation

	void keyPressed(evt)

	{

		if(evt.getKeyCode() == KeyEvent.VK_ESCAPE)

			dialog.dispose();

	}



	void keyReleased(evt){}

	void keyTyped(evt){}

	// }}}



	// {{{ add listeners

	dialog.addKeyListener(this);

	ok.addActionListener(this);

	close.addActionListener(this);

	// }}}



	// {{{ display dialog

	dialog.pack();

	dialog.setLocationRelativeTo(view);

	dialog.setDefaultCloseOperation(JDialog.DISPOSE_ON_CLOSE);

	dialog.setVisible(true);

	// }}}



}



IRCChannelDialog();